VBA-将数据从存储阵列复制到工作表阵列时出现问题

编程问答 2022-08-23

问题描述

我正在尝试在VBA中复制Excel中数据表的功能。到目前为止，我已经按照我想要的方式工作了，但是当我从临时存储阵列中复制数据时，它偏移了1列和1行。

我不知道是什么问题？预先感谢。


Sub DataTableLoop()

Application.Calculation = xlCalculationManual
Application.ScreenUpdating = False

Dim CodeRng As Range
Dim PasteRng As Range
Dim WatchRng As Range
Dim ResultRng As Range
Dim ResultRes As Range
Dim x As Integer
Dim y As Integer
Dim i As Integer
Dim Count As Integer
Dim col As Integer
Dim MyArray As Variant
Dim TempArr As Variant
Dim CodeVar As Range

Set CodeRng = Worksheets("OptionCodes").[Codetop]
Set PasteRng = Worksheets("OptionCodes").[OptionsCode]
Set WatchRng = Worksheets("OptionCodes").[WatchRange]
Set ResultRng = Worksheets("OptionCodes").[ResultsRange]

col = WatchRng.Columns.Count

x = Worksheets("OptionCodes").[Iterations].Value
y = x - 1
i = 0

Set ResultRes = ResultRng.Resize(x)

ReDim MyArray(x,col)

do while i <= y

Set CodeVar = CodeRng.Offset(i,0)

Count = i + 1

Application.StatusBar = "Iteration: " & Count & " of " & x

    CodeVar.copy
    PasteRng.PasteSpecial Paste:=xlPasteValues

        Application.Calculate
    
    TempArr = WatchRng
    For j = 1 To col
        MyArray(Count,j) = TempArr(1,j)
    Next j
    
i = i + 1

Loop

ResultRes = MyArray

Application.ScreenUpdating = True

Application.Calculation = xlCalculationAutomatic

End Sub

解决方法

Redim默认情况下是基于0的，因此您的数组实际上比您期望的大1列。要基于1，您需要指定下限

ReDim MyArray(1 To x,1 To col)
arraysarrayscopyexcelexcelloops