批处理文件：在另一列中合并两列的字符串

问题描述

我目前正在尝试自动执行csv数据的预处理过程。我的csv表如下所示：

id;      town;   nrlanes;   direction;   name;            x;       y;        edgeid;     
129001;  Wales;  1;         Scottland;   Scottland B10;   54529;   338288;   E332;
111002;  Wales;  2;         London;      London B12;      54529;   338288;   E304;
334003;  Wales;  3;         Ireland;     Ireland B3;      54529;   338288;   E303;

我要执行的操作是使用列ID（应切掉最后3位数字！）和方向（+字符串“ Ri。”）的组合覆盖“名称”列方向）。结果表应如下所示：

id;      town;   nrlanes;   direction;   name;                x;       y;        edgeid;     
129001;  Wales;  1;         Scottland;   129 Ri. Scottland;   54529;   338288;   E332;
111002;  Wales;  2;         London;      111 Ri. London;      54529;   338288;   E304;
334003;  Wales;  3;         Ireland;     334 Ri. Ireland;     54529;   338288;   E303;

这是我到目前为止尝试过的：

@echo off
REM for /f "tokens=1,2,3,4,5,6,7,8 delims=;" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do echo %%a;%%b;%%c;%%d;%%~a Ri. %%~d;%%e;%%f;%%g >> "%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%"

(
for /F "tokens=1-8* delims=;" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do (
  set id=%%a
  set id_cut=%id:~-3%
  set merged_columns=%id_cut% Ri. %%~d
  echo %%a;%%b;%%c;%%d;%%e;%merged_columns%;%%f;%%g
 )
)>> "%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%"

我读过另一个线程，其中％var_name：〜-3％剪切字符串的最后三位，这正是我所需要的。这是我的bat文件版本的结果：

id;      town;   nrlanes;   direction;   ;   x;       y;        edgeid;     
129001;  Wales;  1;         Scottland;   ;   54529;   338288;   E332;
111002;  Wales;  2;         London;      ;   54529;   338288;   E304;
334003;  Wales;  3;         Ireland;     ;   54529;   338288;   E303;

如您所见，列“名称”为空，列名称“名称”为空。我在这里做错了什么？有什么建议吗？

解决方法

您需要delayedexpansion

请注意，我必须将%替换为!才能扩展变量，这些变量在括号循环中为set。我还假设您没有所有空格？

@echo off
setlocal enabledelayedexpansion
(for /F "skip=1 tokens=1-6* delims=;" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do (
   set "id=%%a"
   echo %%a;%%b;%%c;%%d;!id:~0,-3! Ri. %%~d;%%f;%%g
 )
)>"%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%"

最后，请考虑您的结果将对标头执行的操作，如果不需要这样做，则需要skip=1然后修改标头以适合您的需要。这是保留原始标头的示例：

@echo off
setlocal enabledelayedexpansion
for /F "delims=" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do (
   (echo %%a)>"%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%" & goto :file
)
:file
(for /F "skip=1 tokens=1-6* delims=;" %%a in (%PREPROCESSING_OUTPUT_PATH%temp.csv) do (
   set "id=%%a"
   echo %%a;%%b;%%c;%%d;!id:~0,-3! Ri. %%~d;%%f;%%g
 )
)>>"%PREPROCESSING_OUTPUT_PATH%%OUTPUT_FILENAME%"

batch-file cmd cmd csv csv csv substring substring