在Stata中使用并行列表生成新变量

问题描述

我正在尝试从Stata中的两个并行列表中生成一组新的变量。我有一组列，分别是劳动力中每个人口统计群体的百分比，还有一组列，是特定职业中每个人口统计群体的百分比。我想将后者除以前者，以为每个组创建一个拥挤得分。

local pct_lf "pct_lf_tot_Male-pct_lf_tot_o_f_65_plus
* pct in labor force by demo group
local pct_occ "pct_Male-pct_o_f_65_plus" 
* pct in occupation by demo group
local n : word count `pct_occ'

forvalues i = 1/`n' {
     local a : word `i' of `pct_lf'
     local b : word `i' of `pct_occ' 
     gen crd_`b'=`b'/`a'
}

此代码存在语法错误，我没有弄清楚。我想知道还有另一种方法吗？通过将一个变量列表除以另一个变量列表以并行列表的顺序来生成新变量？

解决方法

代码不正确。 word＃of不会取消缩写。

关于单词的规则是单词之间用空格分隔，引号除外。此处的异常无关紧要。因此，每个通配符varlist都是一个单词。

. display `: word count "pct_lf_tot_Male-pct_lf_tot_o_f_65_plus"'
1

没有您的数据，我们将无法进行任何真实的测试，但是有把握的猜测是您需要更多类似的东西

unab pct_lf : pct_lf_tot_Male-pct_lf_tot_o_f_65_plus
* pct in labor force by demo group
unab pct_occ : pct_Male-pct_o_f_65_plus 
* pct in occupation by demo group

local n : word count `pct_occ'

forvalues i = 1/`n' {
     local a : word `i' of `pct_lf'
     local b : word `i' of `pct_occ' 
     gen crd_`b'=`b'/`a'
}