Modelica扩展连接器最佳做法 使用总线适配器的替代方法

问题描述

这是我的模型中发生的一些可扩展连接器用法的最小工作示例：

model TestExpandableConnector
  expandable connector ControlBus
    extends Modelica.Icons.SignalBus;
    Real signal1;
    Real signal2;
  end ControlBus;

  ControlBus controlBus;

  // example models to connect signals to
  Modelica.Blocks.Math.Gain gain1;
  Modelica.Blocks.Math.Gain gain2;
  // and so on
equation 
  connect(controlBus.signal1,gain1.u);
  connect(controlBus.signal2,gain2.u);
  // and so on
end TestExpandableConnector;

这很好用，这里不用担心。

请注意，通常该模型将在图形层中使用图形对象以及总线和组件之间的连接（在这种情况下为收益）创建。

虽然上面的示例很简单，但是在许多实际示例中，我从该一个可扩展连接器中出现了许多连接。这种情况很快就会在图表层变得混乱，我正在尝试在此处学习/开发一些最佳实践以清理图表。

一种选择似乎是以几乎等同于Simulink的From / Goto元素的方式使用RealExpression块。例如：

model TestExpandableConnectorRevised
  expandable connector ControlBus
    extends Modelica.Icons.SignalBus;
    Real signal1;
    Real signal2;
  end ControlBus;

  ControlBus controlBus;

  // example models to connect signals to
  Modelica.Blocks.Math.Gain gain1;
  Modelica.Blocks.Math.Gain gain2;
  // and so on

  // using RealEpressions like goto tags
  Modelica.Blocks.sources.RealExpression realExpression1(y=controlBus.signal1);
  Modelica.Blocks.sources.RealExpression realExpression2(y=controlBus.signal2);
  // and so on
equation 
  connect(realExpression1.y,gain1.u);
  connect(realExpression2.y,gain2.u);
  // and so on
end TestExpandableConnectorRevised;

现在有了这种更改，Dymola抱怨这是非法的，因为无法确定因果关系。我似乎能够解决以下问题：1）在总线中的signal1和signal2声明中添加“输入”前缀，或者2）将contolBus声明的RealExpressions声明放置在之前 （第二种解决方案对我来说有点奇怪）。

总体而言，从使我的图表混乱的角度来看，我对这些解决方案感到很满意，但它们也至少感觉有些“ hacky”。我在这个问题上的基本目标是询问这种方法是否可行，或者是一个坏主意？另外，如果还有其他关于如何处理大型模型（尤其是带有可扩展连接器）中所有连接的组织的建议，我非常高兴。另一个想法是，在我看来，Modelica语言更专用的“ From / Goto”功能在Modelica中可能真的很不错，纯粹是为了整理图表，但它完全等同于幕后的connect语句。

解决方法

Dymola抱怨

变量controlBus.signal1是可扩展连接器的一部分，仅用于 连接之外。这是不合法的，因为我们无法确定其因果关系。

使用连接将信号写入某处后，您修改后的解决方案便会起作用 声明。下面，我进一步简化了您的示例，使其仅包含signal1。额外的实数表达式用于设置其值。

model TestExpandableConnectorRevised
  expandable connector ControlBus
     Real signal1;
  end ControlBus;

  ControlBus controlBus;
  Modelica.Blocks.Math.Gain gain1;
  Modelica.Blocks.Sources.RealExpression realExpression1(y=controlBus.signal1);

  // Added to write the bus signal
  Modelica.Blocks.Sources.RealExpression realExpression3(y=1);

equation 
  connect(realExpression1.y,gain1.u);

  // Added to write the bus signal
  connect(realExpression3.y,controlBus.signal1);
end TestExpandableConnectorRevised;

该示例以Dymola pedantic模式和OpenModelica编译，因此应该很好。

使用总线适配器的替代方法

如您所见，可扩展连接器充满了陷阱。如果您决定在可扩展连接器上将signal1重命名为mysignal，但是忘记将connect语句更新为connect(realExpression3.y,controlBus.mysignal)，上述问题也很容易发生。

因此，某些Modelica库仅通过总线适配器决定读取和写入总线信号。您必须为每个变量创建2个其他块：一个要读取，另一个要写入其值。这是很多无聊的工作，但是可以避免上面的问题。

这是读写signal1的最小示例。

package BusAdapters
  partial block BusWriter
    // Dialog allows to set the value of y in the parameter window,like for the real expression
    Modelica.Blocks.Interfaces.RealInput u annotation (Dialog);
    ControlBus controlBus;
  end BusWriter;

  block Write_signal1
    extends BusWriter;
  equation 
    connect(u,controlBus.signal1);
  end Write_signal1;

  partial block BusReader
    Modelica.Blocks.Interfaces.RealOutput y;
    ControlBus controlBus;
  end BusReader;

  block Read_signal1
    extends BusReader;
  equation 
    connect(y,controlBus.signal1);
  end Read_signal1;

  expandable connector ControlBus
    extends Modelica.Icons.SignalBus;
    Real signal1;
  end ControlBus;

  model TestBusConnectors
    ControlBus controlBus;
    Modelica.Blocks.Math.Gain gain1;

    // setting bus variables: using modifiers in write blocks
    Write_signal1 write1(u=sin(time));

    // accessing bus variables part 1: creating instance of reader
    Read_signal1 read1;
  equation 
    // connect all read and write blocks to the same bus instance
    connect(write1.controlBus,controlBus);
    connect(read1.controlBus,controlBus);

    // accessing bus variables part 2: connecting reader with component of interest
    connect(read1.y,gain1.u);
  end TestBusConnectors;
end BusAdapters;

以图形方式显示如下。 x是使用总线适配器直接编写的。对于y，使用实数表达式来减少较大模型中的行数。