jenkins-列出每个并行分支的阶段

问题描述

我得到的代码列出了我的管道的所有分支和阶段

def List getBranchResults() {
    def visitor = new PipelineNodeGraphVisitor(currentBuild.rawBuild)
    echo "${visitor}"
    def branches = visitor.pipelineNodes.findAll{
        it.type == FlowNodeWrapper.NodeType.ParaLLEL 
    }
    def stages = visitor.pipelineNodes.findAll{
        it.type == FlowNodeWrapper.NodeType.STAGE
    }
    echo "${stages}"
    def results = branches.collect{
        branch -> [ 
        id: branch.id,displayName: branch.displayName,result: "${branch.status.result}",]
    }
    echo "Branch results:\n" + results.join('\n')
}
def build_jobs = [:]
def build_results
build_jobs['1'] = {
    node('dvp_hal_builder'){
        stage('A'){
            sh 'echo 1'
        }
        stage('B'){
           "error"
        }
    }
}
build_jobs['2'] = {
    node('dvp_hal_builder'){
        sh 'echo 2'
    }
}
build_jobs['3'] = {
    node('dvp_hal_builder'){
        stage('A'){
            sh 'echo 3'
        }
        stage('B'){
            
        }
    }
}
parallel build_jobs
getBranchResults( )

如何在这两个之间建立联系？ 我想为每个阶段打印它。我也想为每个分支打印失败的阶段（如果存在）

例如：

Branch results:
[id:15,displayName:1,result:SUCCESS]
Stage results for 1:
[id=55,displayName=A,type=STAGE]
[id=25,displayName=B,type=STAGE] - FAILURE

解决方法

我们可以通过查询FlowNode.allEnclosingIds来关联分支和子阶段 对于每个节点。如果此列表包含分支ID，则我们有一个子阶段。

我已经在下面的功能getStageResultsForBranch()中实现了此功能。它似乎与示例代码一起使用。如果阶段具有嵌套的子阶段，它将也返回这些子阶段，这可能不是您想要的。

示例代码：

import io.jenkins.blueocean.rest.impl.pipeline.PipelineNodeGraphVisitor
import io.jenkins.blueocean.rest.impl.pipeline.FlowNodeWrapper

@NonCPS
def List getBranchResults() {

    def visitor = new PipelineNodeGraphVisitor(currentBuild.rawBuild)

    def branches = visitor.pipelineNodes.findAll{
        it.type == FlowNodeWrapper.NodeType.PARALLEL 
    }

    def results = branches.collect{ branch -> [ 
        id: branch.id,displayName: branch.displayName,result: "${branch.status.result}",]}
    
    return results
}

@NonCPS
def List getStageResultsForBranch( String branchId ) {

    def visitor = new PipelineNodeGraphVisitor(currentBuild.rawBuild)

    def childStages = visitor.pipelineNodes.findAll{ stage ->
        stage.type == FlowNodeWrapper.NodeType.STAGE &&
        stage.node.allEnclosingIds.contains( branchId )
    }
    
    def results = childStages.collect{ stage -> [ 
        id: stage.id,displayName: stage.displayName,result: "${stage.status.result}",]}
    
    return results
}

node {
    def build_jobs = [:]
    def build_results
    
    build_jobs['1'] = {
        stage('1.A'){
            sh 'echo 1'
        }
        stage('1.B'){
           error 'an error'
        }
    }
    build_jobs['2'] = {
        sh 'echo 2'
    }
    build_jobs['3'] = {
        stage('3.A'){
            sh 'echo 3'
        }
        stage('3.B'){
                        
        }
    }
    
    try {
        parallel build_jobs
    }
    finally {
        stage('Final') {
            for( branchRes in getBranchResults() ) {
                def stageResults = getStageResultsForBranch( branchRes.id )

                echo "BRANCH RESULT: $branchRes\n" +
                     "  STAGE RESULTS:\n  ${stageResults.join('\n  ')}"
            }
        }
    }
}

（我已删除了构建作业节点以进行测试）

输出：

BRANCH RESULT: [id:8,displayName:1,result:FAILURE]
  STAGE RESULTS:
  [id:12,displayName:1.A,result:SUCCESS]
  [id:29,displayName:1.B,result:FAILURE]

BRANCH RESULT: [id:9,displayName:2,result:SUCCESS]
  STAGE RESULTS:

BRANCH RESULT: [id:10,displayName:3,result:SUCCESS]
  STAGE RESULTS:
  [id:15,displayName:3.A,result:SUCCESS]
  [id:21,displayName:3.B,result:NOT_BUILT]