运行多个snakemake规则

问题描述

我想使用snakemake一个接一个地运行多个规则。但是，当我运行此脚本时，bam_list规则出现在samtools_markdup规则之前，并给我一个错误，即它无法找到显然尚未生成的输入文件。如何解决这个问题？

rule all:
    input: 
        expand("dup/{sample}.dup.bam",sample=SAMPLES)
        "dup/bam_list"

rule samtools_markdup:
    input:
        sortbam ="rg/{sample}.rg.bam"
    output:
        dupbam = "dup/{sample}.dup.bam"
    threads: 5
    shell:
        """
        samtools markdup -@ {threads} {input.sortbam} {output.dupbam}
        """

rule bam_list:
    output:
         outlist = "dup/bam_list"
    shell:
         """
         ls dup/*.bam > {output.outlist}
         """

解决方法

Snakemake遵循指示，您想要dup/bam_list，它可以不经任何输入即可生产。我想你的意思是：

rule all:
    input: 
        "dup/bam_list"

rule samtools_markdup:
    input:
        sortbam ="rg/{sample}.rg.bam"
    output:
        dupbam = "dup/{sample}.dup.bam"
    threads: 5
    shell:
        """
        samtools markdup -@ {threads} {input.sortbam} {output.dupbam}
        """

rule bam_list:
    input: 
        expand("dup/{sample}.dup.bam",sample=SAMPLES)
    output:
        outlist = "dup/bam_list"
    shell:
         """
         ls dup/*.bam > {output.outlist}
         """

现在bam_list将等待所有samtools_markdup作业完成。顺便说一句，我希望dup_list的内容与expand("dup/{sample}.dup.bam",sample=SAMPLES)相同，因此，如果稍后在工作流中使用该文件，则可能只使用扩展输出即可。

bam snakemake