问题：在FPGADE1-SOC上实现超声波传感器HC-SR04

问题描述

我的目标是在我的FPGA（DE1-SOC）上安装一个超声波传感器（HC-SR04），以便我的LED的值根据障碍物的距离而变化。

我正在VHDL中开发QUARTUS II。我的问题是，当我上传到卡中时，没有LED点亮。

我有以下代码：

library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;

entity SENSOR is
    port (
        clk : in std_logic;
        rst : in std_logic;

        trig : out std_logic;
        echo : in  std_logic;

        LEDR : out std_logic_vector(9 downto 0)
    );
end entity SENSOR;

architecture rtl of SENSOR is
    signal tick_us : std_logic;
    signal tick_us_ctr : integer range 0 to 50;

    signal trig_ctr : integer range 0 to 60_010;
    
    signal echo_width_us : integer range 0 to 40_000;
    signal out_range : std_logic :='0'; -- verifie depassement 40 ms de echo_width_us 
begin
    gen_tick_us : process(clk,rst)
    begin
        if rst = '1' then
            tick_us_ctr <= 0;
            tick_us <= '0';
        elsif rising_edge(clk) then
            if tick_us_ctr >= 50-1 then
                tick_us <= '1';
                tick_us_ctr <= 0;
            else
                tick_us <= '0';
                tick_us_ctr <= tick_us_ctr + 1;
            end if;
        end if;
    end process;

    gen_trig : process(clk,rst)
    begin
        if rst = '1' then
            trig <= '0';
            trig_ctr <= 0;
        elsif rising_edge(clk) and tick_us = '1' then -- every 1 us
            if trig_ctr >= 60_010-1 then -- 60 ms + 10 us
                trig <= '0';
                trig_ctr <= 0;
            elsif trig_ctr = 60_000-1 then -- 60 ms
                trig <= '1';
                trig_ctr <= trig_ctr + 1;
            else
                trig_ctr <= trig_ctr + 1;
            end if;
        end if;
    end process;

    measure_width : process(clk,rst)
    begin
        if rst = '1' then
            echo_width_us <= 0;
            LEDR <= (others => '0');
        elsif rising_edge(clk) and tick_us = '1' then -- every 1 us
            if echo = '1' then
                if echo_width_us < 40_001 then
                    echo_width_us <= echo_width_us + 1;
                else
                    out_range <= '1';
                end if;
            elsif echo = '0' and echo_width_us > 0 then
                if out_range ='1' then 
                    echo_width_us <= 0;
                    out_range <= '0';
                    LEDR <= (others => '0');
                else
                    echo_width_us <= 0;
                    LEDR <= std_logic_vector(to_unsigned(echo_width_us / 58,10));
                    --ledr <= (others => '0');
                    --ledr() >= '1';
                end if;
            end if;
        end if;
    end process;
end architecture;

我知道这是可行的，因为我通过制作TestBench在ModelSim上对其进行了测试：

library ieee;
use ieee.std_logic_1164.all;
use ieee.numeric_std.all;

entity SENSOR_TestBench is
end entity SENSOR_TestBench;

architecture rtl of SENSOR_TestBench is
    signal clk_50 : std_logic;
    signal rst    : std_logic;
    
    signal trig : std_logic;
    signal echo : std_logic;
    
    signal ledr : std_logic_vector(9 downto 0);
begin
    uut : entity work.SENSOR
        port map (
            clk => clk_50,rst => rst,trig => trig,echo => echo,ledr => ledr
        );
    
    clk_rst : process
    begin
        rst <= '1';
        clk_50 <= '0';
        wait for 10 ns;
        rst <= '0';
        wait for 10 ns;
        
        for i in 0 to 50 * 1000 * 1000 loop
            clk_50 <= '1';
            wait for 10 ns;
            
            clk_50 <= '0';
            wait for 10 ns;
        end loop;
    end process;
    
    process
    begin
        echo <= '0';
        wait for 100 ns;
        
        wait until trig = '1';
        wait for 10 us;
        echo <= '1';
        wait for 5 ms;
        echo <= '0';
        
        wait until trig = '1';
        wait for 10 us;
        echo <= '1';
        wait for 10 ms;
        echo <= '0';
        
        wait until trig = '1';
        wait for 10 us;
        echo <= '1';
        wait for 25 ms;
        echo <= '0';
        
        wait until trig = '1';
        wait for 10 us;
        echo <= '1';
        wait for 50 ms;
        echo <= '0';
        
    end process;
end architecture;

Simu ModelSim

我也不认为这是PIN映射问题，我尊重该卡的用户手册：

Mapping PINs

我将从QUARTUS II开始，所以我可能忘记了将代码上传到卡中的步骤：

Programmer Quartus

我还在树莓派上测试了我的超声波传感器，看它是否完好无缺，但是运行良好：

Test Ultrasonic sensor on Raspberry

我不知道该怎么办，如果有人有主意，我会全力以赴：D

感谢您的回答！

解决方法

如果不确定Quartus正在进行的操作。我建议您从一个简单的时钟分频器（即一个大计数器）开始，然后将MSB分配给输出LED。 看到led切换后，您将知道实现步骤和编程步骤都是正确的。 然后，您可以返回到特定的传感器模块。