VBA复制基于列标题名称的一列的UsedRange

问题描述

我试图根据列名将数据从一个工作表复制到另一个工作表。在源工作表中，数据从A1开始。在目标工作表中，数据应粘贴在A11行而不是A1行。如果我使用EntireColumn.copy，则会收到有关源和目标副本区域不同的错误。我遇到过UsedRange属性，但是我不愿意将其应用于我的方案

    For Each columnName In allColumns
    'call a function to get the column to copy 
    If columnTocopy > 0 Then
        columnName.Offset(1,0).EntireColumn.copy Destination:=ws2.Cells(11,columnTocopy)
    End If
Next

在以上代码段中，In不想使用'EntireColumn'。我只想要有数据的列。变量columnName例如是'Person ID'

做到这一点的最佳方法是什么？

谢谢。

解决方法

这是一种典型的方法：

    For Each ColumnName In allColumns
        If columnToCopy > 0 Then
            With ColumnName.Parent
                .Range(ColumnName.Offset(1,0),.Cells(.Rows.Count,ColumnName.Column).End(xlUp)).Copy _
                              Destination:=ws2.Cells(11,columnToCopy)
            End With
        End If
    Next

假设allColumns是单单元格范围/列标题的集合。

,

复制/粘贴列

由于没有足够的信息来给出准确的答案，因此您可以考虑研究这种情况。

代码

Option Explicit

Sub TESTdetermineColumnNumber()
    
    ' Define constants. Should be more.

    ' Define Criteria.
    Const Criteria As String = "Total"
    ' Define Header Row.
    Const hRow As Long = 1

    ' Define Copy Range (Column Range)

    ' Define Source Worksheet.
    Dim ws As Worksheet
    Set ws = ThisWorkbook.Worksheets("Sheet1")
    ' Define Header Row Range.
    Dim RowRange As Range
    Set RowRange = ws.Rows(hRow)
    ' Determine Column Number.
    Dim ColumnNumber As Long
    ColumnNumber = determineColumnNumber(RowRange,Criteria)
    ' Validate Column Number.
    If ColumnNumber = 0 Then
        Exit Sub
    End If
    ' Determine Last Row.
    Dim LastRow As Long
    LastRow = ws.Cells(ws.Rows.Count,ColumnNumber).End(xlUp).Row
    ' Define First Data Row Number.
    Dim FirstRow As Long
    FirstRow = hRow + 1
    ' Define Column Range.
    Dim ColumnRange As Range
    Set ColumnRange = ws.Cells(FirstRow,ColumnNumber) _
                        .Resize(LastRow - FirstRow + 1)

    ' Define Paste Range.

    ' Define Destination Worksheet.
    Dim ws2 As Worksheet
    Set ws2 = ThisWorkbook.Worksheets("Sheet2")
    ' Define Destination Column.
    Dim columnToCopy As Long
    columnToCopy = 2
    ' Define Paste Range.
    Dim PasteRange As Range
    Set PasteRange = ws2.Cells(11,columnToCopy)

    ' Copy/Paste.

    ' Copy values,formulas and formats.
    ColumnRange.Copy Destination:=PasteRange
    ' It is more efficient if you need only values to use the following:
    PasteRange.Resize(ColumnRange.Rows.Count).Value = ColumnRange.Value
    
End Sub

Function determineColumnNumber(RowRange As Range,_
                               Criteria As String) _
         As Long
    Dim Temp As Variant
    Temp = Application.Match(Criteria,RowRange,0)
    If Not IsError(Temp) Then
        determineColumnNumber = Temp
    End If
End Function