仅当单元格值更改时，如何执行指令？

问题描述

我有一个ByVal代码来清除表中特定范围的内容，它可以工作。但是，如果范围值（内容）发生变化，而不是仅将光标放在上面，则需要为执行指令添加条件。

此外，有人知道如何在VBA中引用表列？现在，我使用的估计范围是“ C1：C999”，但我想使用他的名字“ A_ [OPERATION]”。

这是代码：

Private Sub Worksheet_SelectionChange(ByVal Target As Range)

   If Not Application.Intersect(Range("C1:C999"),Range(Target.Address)) Is nothing Then
    
       Range(Selection,Selection.End(xlToRight)).ClearContents

   End If

End Sub

解决方法

您可以改用change事件。

以下是文档的链接： https://docs.microsoft.com/en-us/office/vba/api/excel.worksheet.change

或者，您可以将目标单元格的值保存在变量中，并在执行清除内容之前检查该值是否已更改。

对于第二个问题，您可能应该在另一篇文章中进行询问。

工作表更改

调整表名（tName）和标题（列）名（hName）。
我已经对其进行了调整，以清除列后单元格中的内容。
如果您确实还需要清除该列的内容，则将cel.Offset(,1)替换为cel。
在表格中，如果手动或通过VBA更改了列中的值，则当前设置将自动清除指定列右侧的所有单元格的内容。如果该列包含公式，则将无法使用。还支持非连续删除。

代码

Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
    
    Const ProcName As String = "Worksheet_Change"
    On Error GoTo clearError
    
    Const tName As String = "A_"
    Const hName As String = "OPERATION"
    
    Dim rng As Range
    Set rng = Range(tName & "[" & hName & "]")
    Set rng = Intersect(rng,Target)
    If rng Is Nothing Then GoTo ProcExit
    
    Application.EnableEvents = False
    
    With ListObjects(tName).HeaderRowRange
        Dim LastColumn As Long
        LastColumn = .Columns(.Columns.Count).Column
    End With
    Dim cel As Range
    For Each rng In rng.Areas
        For Each cel In rng.Cells
            With cel.Offset(,1)
                .Resize(,LastColumn - .Column + 1).ClearContents
            End With
        Next cel
    Next rng

CleanExit:
    Application.EnableEvents = True
    GoTo ProcExit

clearError:
    Debug.Print "'" & ProcName & "': " & vbLf _
              & "    " & "Run-time error '" & Err.Number & "':" & vbLf _
              & "        " & Err.Description
    On Error GoTo 0
    GoTo CleanExit

ProcExit:

End Sub

Worksheet_Change事件句柄捕获单元格值的变化。

但是，即使是错误的更改，此句柄也会触发。例如，如果更改前的单元格值为“ A”，并且用户再次在该单元格中输入了“ A”，则无论如何都会触发Change事件过程。

为避免这种情况，我们可以同时使用Worksheet_Change和Worksheet_SelectionChange。

使用Worksheet_SelectionChange，我们将旧值记录在某个地方，例如Name。然后使用Worksheet_Change，我们可以将用户输入的内容与Name进行比较，以查看是否进行了真正的更改。

Private Sub Worksheet_SelectionChange(ByVal Target As Range)
    Dim Nm As Name: Set Nm = ActiveWorkbook.Names("OldValue")
    If Target.Count = 1 Then
        'This only record one old cell value.
        'To record multiple cells old value,use a hidden Worksheet to do so instead of a Name.
        Nm.Comment = Target.Value2
    else
        Nm.Comment = Target.Value2(1,1)
    End If
End Sub

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim Nm As Name: Set Nm = ActiveWorkbook.Names("OldValue")
    If Target.Value2 <> Nm.Comment Then
        Debug.Print "True change"
    Else
        Debug.Print "False change"
    End If
End Sub

您可以通过listobject对象访问表的方法和属性。以下是如何执行此操作的示例。

Sub Example()
    Dim lo As ListObject
    Dim lc As ListColumn
    Set lo = Range("Table1").ListObject
    Set lc = lo.ListColumns("Column2")
End Sub

也就是说，对于您的情况，应该是Range("A_").ListObject.ListColumns("OPERATION").DataBodyRange。

byval byval excel excel vba