遍历模板 Haskell AST

问题描述

我认为 template-haskell 中的 Haskell 代码没有表示为单个 AST，而是表示为 Pat、Exp、Dec 和 { 四种交叉引用类型{1}}。我在图书馆内或其他任何地方也没有发现任何遍历设施。

我最初是在寻找上述四种类型的统一表示：

Type

现在我越来越相信以这种方式编写它除了费时而且浪费，因为遍历/转换 AST 是一种常见的做法，我认为最好问问有哪些可用的解决方案实践者。

解决方法

一般来说，我不确定 TH 的泛型遍历是否会经常出现。 （我正在努力想象 TH AST 的有用转换，在这种情况下，您不会只生成已经以这种方式转换的 TH。）我想在某些情况下，您想要执行用户提供的查询或转换不解析整个 AST 的 quasiquotes？

无论如何，如果你能找到它的用途，你可以使用 SYB 泛型。例如，这是一个从任意 TH “事物”的模式和表达式中提取文字的查询：

{-# LANGUAGE TemplateHaskell #-}

import Data.Generics
import Language.Haskell.TH

getLiterals :: Data d => d -> [Lit]
getLiterals = everything (++) (mkQ [] litE `extQ` litP)
  where litE (LitE l) = [l]
        litE _ = []
        litP (LitP l) = [l]
        litP _ = []

main = do mydec <- runQ [d| foo 4 = "hello" |]
          print mydec
          print $ getLiterals mydec
          myexp <- runQ [| '1' + "sixteen" |]
          print myexp
          print $ getLiterals myexp

这是一个转换模式、表达式和类型中的所有中缀运算符的转换（未显示 InfixT 的示例）：

{-# LANGUAGE TemplateHaskell #-}

import Data.Generics
import Language.Haskell.TH

causeChaos :: Data d => d -> d
causeChaos = everywhere (mkT destroyExpressions `extT` manglePatterns `extT` bludgeonTypes)
  where destroyExpressions (InfixE l x r) = InfixE r x l
        destroyExpressions (UInfixE l x r) = UInfixE r x l
        destroyExpressions e = e
        manglePatterns (InfixP l x r) = InfixP r x l
        manglePatterns (UInfixP l x r) = UInfixP r x l
        manglePatterns e = e
        bludgeonTypes (InfixT l x r) = InfixT r x l
        bludgeonTypes (UInfixT l x r) = UInfixT r x l
        bludgeonTypes e = e

main = do mydec <- runQ [d| append :: [a] -> [a] -> [a]
                            append (x:xs) ys = x : append xs ys
                            append [] ys = ys
                         |]
          print mydec
          print $ causeChaos mydec