使用 megaparsec 链接一元运算符

问题描述

我使用 megaparsec 为一种非常简单的语言编写了一个解析器，该语言由整数文字和两个一元运算符“a”和“b”组成：

data ValueExpr = OpA ValueExpr  
               | OpB ValueExpr
               | Integer Integer

valueExpr :: Parser ValueExpr
valueExpr = makeExprParser valueTerm valueOperatorTable

valueTerm :: Parser ValueExpr
valueTerm = parenthesised valueExpr
          <|> Integer <$> integerLiteral

integerLiteral :: Parser Integer
integerLiteral = -- omitted

valueOperatorTable :: [[Operator Parser ValueExpr]]
valueOperatorTable = [[unaryOp "a" AOp,unaryOp "b" BOp]]

parenthesised :: Parser a -> Parser a
parenthesised = between (char '(') (char ')')

unaryOp :: Text -> (a -> a) -> Operator Parser a
unaryOp name f = Prefix (f <$ symbol name)

binaryOp :: Text -> (a -> a -> a) -> Operator Parser a
binaryOp name f = InfixL (f <$ symbol name)

然而，这似乎不允许我“链接”一元运算符，即在尝试解析“ab1”时，我遇到了“意外的‘b’”。这是为什么？

解决方法

这在 makeExprParser 的 documentation 中简要提及：

相同优先级的一元运算符只能出现一次（即，如果 --2 是前缀否定，则不允许出现 -）。如果您需要连续解析多个前缀或后缀运算符，...您可以使用这种方法：

manyUnaryOp = foldr1 (.) <$> some singleUnaryOp

默认情况下不会这样做，因为在某些情况下，不允许重复前缀或后缀运算符。

在您的具体示例中，应该可以使用以下内容：

valueOperatorTable :: [[Operator Parser ValueExpr]]
valueOperatorTable = [[Prefix unaryOps]]

unaryOps :: Parser (ValueExpr -> ValueExpr)
unaryOps = foldr1 (.) <$> some (OpA <$ symbol "a" <|> OpB <$ symbol "b")

haskell haskell megaparsec