寻找季节性效应的自变量？

问题描述

我不确定在这里问这个问题是否正确，但非常感谢任何帮助。我在 sas 预测工作室工作。

这是我的时间序列数据集（季度数据）：

日期例如80 年 1 月 1 日、80 年 4 月 1 日、80 年 7 月 1 日
DateQ 例如1980Q1、1980Q2、1980Q3
年份例如1980、1981、1982
GDP（可靠变量）例如2650.1
T 例如1、2、3

这个变量中的哪个，或者我应该创建一个新的季度变量，作为线性回归的自变量来评估是否有任何季节性影响？

解决方法

在分析时间序列数据时，不应使用对时间变量的简单线性回归来识别季节性影响。但是，要回答您的问题，请使用 date 和 intnx() 函数将其转换为四分之一。

data want;
    format quarter yyq.;
    set have;
    quarter = intnx('quarter',date,'B');
run;

可以通过多种方式识别季节性影响：

1.绘图

如果一个时间序列有季节性影响，它会趋于清晰。只需查看数据图表，您就可以知道它是否按您选择的时间间隔具有季节性。

在 sashelp.air 中，很明显有一个 12 个月的季节。

2.光谱密度分析

proc timeseries 将为您提供频谱分析，以帮助识别数据中的重要季节。峰值表示可能的周期或季节。您需要对合理的季节性数量进行一些过滤，因为在某一点之后密度可能会显着增加，并且不能代表真实的季节。

Forecast Studio 和 Time Series Studio 将为您执行此操作，并可以为您提供与以下类似的输出。

proc timeseries data=sashelp.air 
                outspectra=outspectra;
    id date interval=month;
    var air;
    spectra;
run;

proc sgplot data=outspectra;
    where period BETWEEN 1 AND 24;
    scatter x=period y=p;
    series x=period y=p;
run;

我们可以看到 12 的季节性很强的指标。我们还看到了一些潜在的 3 个月和 6 个月周期，可以在模型中测试其显着性。

3. ACF/PACF/IACF 图 您在 Forecast Studio 中的 ACF/PACF/IACF 图也将帮助您识别晴朗的季节。

经典的腐朽悬索桥外观表明季节性影响。请注意，季节在 12 左右增加，然后再次减少。此外，PACF 和 IACF 图中 12 处的显着负峰值是 12 处显着季节性效应的其他指标。

模型构建和测试

Forecast Studio 中的 seasonal augmented dickey fuller test 等工具可帮助您确定是否已捕捉到季节性并在差分后实现平稳。

系列视图中的选择框允许您快速添加简单或季节性差异。选择 (1) 进行简单差分将添加一个简单差分。即：

y = y - lag(y)

为季节性差异选择 (1) 将增加 1 个季节性差异。请注意，在 Forecast Studio 中创建项目时，会自动诊断和假设季节。这应该在完成我们上面的诊断之后完成，以便我们最好地猜测真正的季节是什么。在我们的例子中，我们假设我们的赛季是 12。这相当于：

y = y - lag12(y)

然后我们可以使用平稳性测试来确保我们已经达到平稳性。在我们的例子中，我们将添加 1 个简单的季节性差异。

请注意我们的白噪声图是如何改进的，并且我们在 12 处的峰值已经降低到不显着。此外，我们的平稳性检验看起来不错且显着 - 也就是说，不存在单位根。

添加季节性或周期性影响

您的模型选择将决定如何添加季节性或周期性影响。 ARIMA 模型中的差分将处理季节性。虚拟变量可用于 ARIMA 模型中的附加周期性效应。例如：

data want;
    set have;
    q1 = (qtr(date) = 1);
    q2 = (qtr(date) = 2);
    q3 = (qtr(date) = 3);
run;

UCM 可以通过添加季节性和周期性影响来解决所有这些问题。 Holt-Winters ESM 无需虚拟变量即可处理趋势和季节性。您对每种模型的建模目标和性能考虑将决定您选择哪种模型。

forecast sas sas-studio