查询 kz dachau 指挥官的维基数据语法

问题描述

我是 wikidata 的新手，我曾尝试使用 sparql 查询 kz dachau 指挥官的开始/结束日期。我有以下代码，但我没有得到任何数据。

SELECT ?KZ_Dachau ?start ?end ?name
WHERE
  {?KZ_Dachau p:P1037 ?leiter.
  ?leiter ps:P1037 wd:Q151198;
          pq:P580 ?start;
          pq:P582 ?end.
   ?KZ_Dachau wdt:P1559 ?name. }

我的查询所基于的类似查询工作正常：

SELECT ?papst ?start ?end ?name ?pic
WHERE 
{?papst p:P39 ?position.
?position ps:P39 wd:Q19546;
pq:P580 ?start;
pq:P582 ?end.
?papst wdt:P1559 ?name.}

我做错了什么？

我认为我的方法是错误的，但我不知道如何解决它：/我不明白，为什么我不能选择实体 kz dachau (Q151198) 的任何属性。

解决方法

问题是您的顺序有误，即在 WikiData 中，物业主管/经理将某人作为对象，而不是您查询中的主题。

此查询将起作用：

SELECT ?KZ_Dachau ?start ?end ?name
WHERE
  {wd:Q151198 p:P1037 ?leiter. #Notice the change in order
  ?leiter ps:P1037 ?KZ_Dachau;
          pq:P580 ?start;
          pq:P582 ?end.
   ?KZ_Dachau wdt:P1559 ?name. }

此外，您可以使用属性路径，在这种情况下，^ 反转属性，因此 ?a :hasChild ?b 将与 ?b ^:hasChild ?a 完全相同：

SELECT ?KZ_Dachau ?start ?end ?name
WHERE
  {?KZ_Dachau ^ps:P1037 ?leiter.
  ?leiter ^p:P1037 wd:Q151198;
          pq:P580 ?start;
          pq:P582 ?end.
   ?KZ_Dachau wdt:P1559 ?name. }

另一方面，WikiData 中的 P39 将人作为主题，因此该查询有效。然而，如果你看看 Eicke，维基数据只是说他担任国会议员的职位，并没有说他是达豪的经理/主任。