问题描述
我正在尝试编写一个查询,将一个变量绑定到一个尚未绑定的值。
例如,它可能看起来像这个伪代码:
OPTIONAL {
FILTER (some filter)
BIND ("I bound this variable" as ?variable)
}
OPTIONAL {
FILTER (!BOUND(?variable))
BIND ("This variable was unbound,but is Now bound"
}
基本上,我有一个变量可能有也可能没有分配的值,如果没有,我想分配一个,但我无法使用 FILTER (!BOUND(?variable))
之类的方法进行查询。>
解决方法
您正在寻找的是 COALESCE 函数。 例如,假设您有以下数据:
@prefix : <http://example.com/> .
:john a :Person ;
:hasChild :anna,:will .
:anna a :Person ;
:hasChild :charlie .
:will a :Person .
:charlie a :Person .
然后是 SPARQL 查询:
SELECT ?person ?child
WHERE {
?person a :Person .
OPTIONAL { ?person :hasChild ?c }
BIND(COALESCE(?c,"Has no children.") AS ?child)
}
请注意,COALESCE
可以接受 2 个以上的参数,例如如果我们将数据稍微更改为:
@prefix : <http://example.com/> .
:john a :Person ;
:hasDaughter :anna ;
:hasSon :will .
:anna a :Person ;
:hasSon :charlie .
:will a :Person .
:charlie a :Person .
即我们说如果孩子是儿子还是女儿,那么我们可以发出这样的查询:
SELECT ?person ?child
WHERE {
?person a :Person .
OPTIONAL { ?person :hasDaughter ?daughter }
OPTIONAL { ?person :hasSon ?son }
BIND(COALESCE(?daughter,?son,"Has no children.") AS ?child)
}
如果有一个女儿,这将返回一个女儿。如果失败,它将返回一个儿子,如果失败,它将返回“没有孩子”。