如何在 LISP 中反转列表及其子列表的元素？

编程问答 2022-05-24

问题描述

我有以下一段代码：

(defun list-append (L1 L2)
  "Appending L1 by L2."
  (if (null L1)
      L2
      (cons (car L1) (list-append (cdr L1) L2))))

(defun list-reverse (L)
  "Create a new list containing the elements of L in reversed order."
  (if (null L)
      nil
      (list-append (list-reverse (cdr L)) 
                   (list (car L)))))

当我运行以下命令时：

(list-reverse '(a (b c) ((l k (t)) h i)))

我得到的输出是这样的：

(((L K (T)) H I) (B C) A)

但是，我试图让它像这样反向打印列表及其子列表：

((I H ((T) K L)) (C B) A)

有关如何修改代码以执行此操作的任何建议？

解决方法

这里有一种方法可以做到这一点，但并不可怕。特别是 previous question 的公认解决方案在算法上是可怕的：任何反转列表的方法都说：“反转一个（可能很长的列表），首先反转它的 cdr，然后 附加汽车 应该会让你的皮肤发痒：这种方法就是“lisp 很慢”的原因。另外两个答案更好，但都明确地改变了状态（这很好，但在教学上可能并不总是很好）。

所以这里有一个答案：是函数式的（不会改变状态），并且使用了一种不可怕的算法。

首先，假设我们有一个名为 reverse-thing 的函数，它将对“事物”进行适当的反转，这意味着：如果它是一个列表，则反转它，如果它不是一个列表，则不要'吨。给定该函数，我们可以计算出将列表反转为其他列表的算法：

将一个列表反转到另一个列表

  • 如果列表为空，则返回我们要反转的列表
  • 否则，将列表的其余部分反转到通过将列表的第一个的 reverse-thing 与我们要反转到的列表结合而成的列表。

这个变成函数很简单：

(defun reverse-onto (list onto)
  (if (null list)
      onto
    (reverse-onto (rest list)
                  (cons (reverse-thing (first list))
                        onto))))

所以这个函数需要一个 reverse-thing 的定义才能完成它的工作。那么这将如何运作？

反转事物：

  • 如果它是一个列表，则使用reverse-onto将其反转到()，即空列表；
  • 如果它不是列表，则按原样返回。

再说一次，这很容易变成一个函数：

(defun reverse-thing (thing)
  (if (listp thing)
      (reverse-onto thing '())
    thing))

我们完成了：reverse-thing 是我们想要编写的函数。

请注意，这些函数永远不会改变任何东西，并且永远不会超越它们在每一步中反转的列表的第一个缺点：这里没有“将这个东西附加到这个巨大列表的（副本）”。另请注意，reverse-into 是尾递归的，因此在优化尾调用的实现中（标准不需要），堆栈量将与嵌套深度成正比，而不是列表长度。

clispcommon-lisplisplisplisp