如何在脚本化的 jenkins 管道中定义全局变量

问题描述

我想在 Jenkins 脚本管道中定义一个全局变量，该变量可以在管道中的任何地方访问。即任何阶段，任何方法。如果我在管道顶部定义 var，它在 node 声明和 stage 声明中有效，但在被调用方法中无效。我不想使用 env.XXX 和 withEnv([]) 因为我可能不得不从不同的地方调用这些方法，这意味着有时使用 env 而不是其他。

这是我用于脚本化管道的简单 JenkinsFile：

def jenkinsNode = 'linux'
def DEBUG = 1

node(jenkinsNode){
  echo ">> node($jenkinsNode)"
  echo "DEBUG = $DEBUG"

  if (DEBUG) {
    echo "DEBUG is On"}
  else {
    echo "DEBUG is Off"
  }

  stage('test-this') {
    if (DEBUG) {
      echo "DEBUG is On"}
    else {
      echo "DEBUG is Off"
    }

    testMethod()
  }
  echo "<< node($jenkinsNode)"
}

def testMethod() {
  echo ">> testMethod()"

  if (DEBUG) {
    echo "DEBUG is On"}
  else {
    echo "DEBUG is Off"
  }

  echo "<< testMethod()"
}

当我运行这个时，我得到：

Running on rh6-a01 in /jenkins_home/jenkins-rh6-a01/a98289de/workspace/test/test/test-global
[Pipeline] {
[Pipeline] echo
>> node(linux)
[Pipeline] echo
DEBUG = 1
[Pipeline] echo
DEBUG is On
[Pipeline] stage
[Pipeline] { (test-this)
[Pipeline] echo
DEBUG is Off
[Pipeline] echo
>> testMethod()
[Pipeline] }
[Pipeline] // stage
[Pipeline] }
[Pipeline] // node
[Pipeline] End of Pipeline
hudson.remoting.ProxyException: groovy.lang.MissingPropertyException: No such property: DEBUG for class: WorkflowScript
[...snip...]

我如何编写这个 Jenkinsfile 以允许任何方法访问 DEBUG 变量？

解决方法

从顶部的声明中删除 def 可以解决此问题。

def jenkinsNode = 'linux'
DEBUG = 1

node(jenkinsNode){
  echo ">> node($jenkinsNode)"
  echo "DEBUG = $DEBUG"

  if (DEBUG) {
 .....

给出输出

>> node(linux)
[Pipeline] echo
DEBUG = 1
[Pipeline] echo
DEBUG is On
[Pipeline] stage
[Pipeline] { (test-this)
[Pipeline] echo
DEBUG is On
[Pipeline] echo
>> testMethod()
[Pipeline] echo
DEBUG is On
[Pipeline] echo
<< testMethod()
[Pipeline] }
[Pipeline] // stage
[Pipeline] echo
<< node(docker)
[Pipeline] }
[Pipeline] // node
[Pipeline] End of Pipeline
Finished: SUCCESS

这是因为使用 def 将变量绑定到当前范围（方法内容不在该范围内）。不使用 def 不会绑定范围，允许它在脚本中的任何地方使用。

请注意，Groovy 不会阻止您在其他地方使用带有 def 的变量，这可能会导致意外结果，例如在方法中添加一个 def DEBUG = 0

def testMethod() {
  echo ">> testMethod()"
  def DEBUG = 0

  if (DEBUG) {
    echo "DEBUG is On"}
  else {
    echo "DEBUG is Off"
  }

仍然可以正常运行，但会在该方法中关闭 DEBUG。

您可以将变量作为参数传递

......

    testMethod(DEBUG)
  }
  echo "<< node($jenkinsNode)"
}

def testMethod(DEBUG) {
  echo ">> testMethod()"

  if (DEBUG) {
    echo "DEBUG is On"}
  else {
    echo "DEBUG is Off"
  }

  echo "<< testMethod()"
}

如果上述解决方案不是您要找的，那么使用 @Field 注释将如本答案中所述https://stackoverflow.com/a/37425799/10697591

import groovy.transform.Field

@Field def DEBUG = 1
def jenkinsNode = 'master'


node(jenkinsNode){
  echo ">> node($jenkinsNode)"
  echo "DEBUG = $DEBUG"

  if (DEBUG) {
    echo "DEBUG is On"}
  else {
    echo "DEBUG is Off"
  }

  stage('test-this') {
    if (DEBUG) {
      echo "DEBUG is On"}
    else {
      echo "DEBUG is Off"
    }

    testMethod()
  }
  echo "<< node($jenkinsNode)"
}

def testMethod() {
  echo ">> testMethod()"

  if (DEBUG) {
    echo "DEBUG is On"}
  else {
    echo "DEBUG is Off"
  }

  echo "<< testMethod()"
}

cloudbees jenkins jenkins-pipeline pipeline pipeline