问题描述
我有一个汇编代码,它将一个 COM 文件加载到内存中并运行它。 COM 文件将被加载到单独的数据段,将 DS 和 SS 更改为该段并调用它来运行 COM 文件。 我的数据和堆栈段是:
STACKSEG SEGMENT STACK 'stack'
DW 512 DUP(?)
STACKSEG ENDS
DATASEG1 SEGMENT Para 'data'
stacksp dw 0
stackbp dw 0
DATASEG1 ENDS
DATASEG2 SEGMENT Para 'data'
WHERetoJ:
;stck db 32 dup (?)
txt db 4096 dup (?),"$"
;string B
DATASEG2 ENDS
我的来电者是:
mov stacksp,sp
mov stackbp,bp
ASSUME DS: DATASEG2,SS:DATASEG2
mov ax,DATASEG2
mov DS,AX
mov ES,AX
MOV SS,AX
mov SP,0FFFFh
call far ptr WHERetoJ ; (Now registers are SP:FFFF,BP:0,SI:0C40,DI:0C16,DS:1820,ES:1820,SS:1820,CS:192D,IP:00BD)
ASSUME DS: DATASEG1,SS:STACKSEG
mov ax,STACKSEG
MOV SS,AX
MOV AX,DATASEG1
MOV DS,AX
MOV ES,AX
mov bx,offset stackbp
mov bp,[bx]
mov bx,offset stacksp
mov sp,[bx]
ret
COM 文件只是运行 int 10h 来打印一个字符并且应该返回给调用者:
mov ax,0945h ; (Now registers are changed to SP:FFFB,CS:1820,IP:0000)
mov bx,0006
mov cx,40
int 10h
ret ;; ( registers are SP:FFFB,IP:000B)
;;ret is ran,the registers are: SP:FFFBD,IP:00C2
问题是当运行 COM
文件时,ret
不会返回给调用者,而是返回到错误的未知 IP。
解决方法
您的主要问题是您执行的 RET
是 NEAR 回报。实模式下的 NEAR 返回将导致从堆栈中弹出 16 位偏移量,并将 IP(指令指针)设置为该值。段不会改变。
您的代码:
call far ptr WHERETOJ
是一个 FAR CALL
并推送 16 位代码段 (CS),然后是 16 位 IP。 NEAR RETURN 只弹出 16 位 IP 并将段留在堆栈中。
在 FAR CALL 的那一刻,你说寄存器有:
SP:FFFF,SS:1820,CS:192D,IP:00BD
A CALL
将 CS 和指令的 IP 推送到 CALL
之后。 FAR CALL 编码为 5 字节指令,因此压入堆栈的地址为 192Dh:00C2h (00BDh+5=00C2h)。当您执行 NEAR 返回时,它没有更改 CS,而是将 IP 更改为 00C2h。它也只从堆栈中弹出 2 个字节。这就是您在执行 RET
指令时在调试器中看到的原因:
SP:FFFD、SS:1820、CS:1820、IP:00C2
SP 从 0FFFBh 到 0FFFDh 增加了 2。 CS 保持不变,IP 设置为 00C2h。 CS:IP 对不正确,因此您最终执行了您不打算执行的内存。如果您将 RET
替换为 RETF
(FAR RETURN),那么您的代码将按预期运行,并且在执行 RET
时寄存器将具有以下值:
SP:FFFF、SS:1820、CS:192D、IP:00C2
DOS COM 程序
您使用术语 COM 程序,但您的代码表明它可能是一个二进制文件,其 ORG(原点)为 0000h,而不是 DOS COM 程序中典型的 ORG 0100h。为了与 DOS COM 兼容,您必须在距运行程序的代码段开头 256 字节的偏移处加载代码和数据。在 DOS COM 程序中,执行的第一条指令是 CS:0100h 而不是 CS:0000h
在典型的 DOS COM 程序中,DOS 加载程序将 0000h 压入堆栈顶部。如果您执行将在 CS:0000h 开始执行的 NEAR RET。前 256 个字节包含 DOS Program Segment Prefix (PSP)。 PSP 的前 2 个字节(即 CS:0000h)是 INT 20H
指令。
INT 20h
将终止 DOS COM 程序并向启动该程序的 DOS 命令提示符返回 0 ERRORLEVEL。 INT 20h
不应用于退出 DOS EXE 程序,而应使用 INT 21h/AH=4C
。
如果您想找到一种方法,像 DOS 那样使用 NEAR RETURN 退出程序,那么您必须在代码段内提供一种机制(代码)来执行此操作。由于您没有 DOS PSP(或已选择不使用),您必须找到一个地方来复制该段中的此类代码。最简单的机制是在开始执行程序之前在堆栈上创建一个 code trampoline。最简单的方法是将 FAR CALL(或 FAR JMP)压入堆栈,让您返回到 call far ptr WHERETOJ
指令之后的指令。
FAR CALL 在堆栈上被编码为:
9A oooo ssss
其中 9A
是 FAR CALL 的操作码,oooo
是要调用的偏移量,ssss
是要使用的段。我们希望将堆栈指针 (SP) 保持在偶数对齐1 上,因此我们添加了一条 NOP
指令,总共 6 个字节(6 是偶数数字)。堆栈看起来像:
90 9A oooo ssss
在堆栈上构建 NOP+FAR CALL 后,您需要推送该代码的偏移量,以便 NEAR RET 在执行时最终调用它。
COM 程序中的执行路径将是 NEAR RET (ret
) 导致 IP 更改为 NOP+FAR CALL 所在的堆栈地址并执行该指令回调到最初用于开始执行 COM 程序的 FAR JMP 的位置。您也可以在堆栈上编码一个 NOP+FAR JMP,但是 NOP+FAR CALL 的优点是将 CS 的值推送到堆栈上,这在以后可能会很有用,特别是如果您在内存中加载多个 COM 程序。
为在 8086 或更高版本的处理器上运行而编写的示例程序可能如下所示:
.8086
STACKSEG SEGMENT STACK 'stack'
DW 512 DUP(?)
STACKSEG ENDS
DATASEG1 SEGMENT PARA 'data'
finstr db 0dh,0ah,'Returned from COM program',0dh,'$'
stacksp dw 0
stackbp dw 0
DATASEG1 ENDS
DATASEG2 SEGMENT PARA 'data'
WHERETOJ:
mov ax,0945h
mov bx,0057h
mov cx,40
int 10h
ret
org 65536 ; Expand the segment to 64KiB
DATASEG2 ENDS
CODESEG1 SEGMENT PARA 'code'
main:
ASSUME DS: DATASEG1,SS:STACKSEG
mov [stacksp],SP
mov [stackbp],BP
ASSUME DS: DATASEG2,SS:DATASEG2
mov AX,DATASEG2
mov DS,AX
mov ES,AX ; DS=ES=SS=DATASEG2
; CLI ; If running on BUGGY 8088 you would need to have CLI/STI
MOV SS,AX
xor SP,SP ; SP = 0. Grow down from top of 64KiB SS segment
; STI
; Build FAR CALL on the COM programs stack
; to return to this code when NEAR RET done
push CS ; Put CS on stack as part of FAR CALL
mov AX,offset aftercom
; Push the IP of the instruction after the FAR JMP below
push AX
mov AX,09a90h ; Put a NOP(90h) on the stack and 9AH (FAR CALL opcode)
push AX ; NOP used as padding to keep SP aligned on an even address
mov AX,SP
push AX ; Push a copy of SP on the stack. SP is the address of the
; NOP
; CALL FAR PTR segment:offset instruction built on stack
jmp far ptr WHERETOJ ; Start executing our program code
aftercom:
add SP,10 ; When we return the stack has 10 bytes on it (6 bytes
; for FAR CALL and the NOP + 4 bytes of the CALLers
; IP and CS). Clean them up
ASSUME DS: DATASEG1,SS:STACKSEG
MOV AX,DATASEG1
MOV DS,AX
MOV ES,AX
mov AX,STACKSEG
; CLI ; If running on BUGGY 8088 you would need to have CLI/STI
MOV SS,AX ; Restore SS:SP one after another since interrupts
; will be off until the instruction after changing SS
mov SP,[stacksp]
; STI
mov BP,[stackbp]
mov AH,09 ; Display a string saying we returned
mov DX,offset finstr
int 21h
mov AX,4c00h ; Exit DOS EXE program with ERRORLEVEL 0
int 21h
CODESEG1 ENDS
END main
代码的正常运行版本在运行时看起来与此类似:
脚注
-
1在实模式下,出于性能原因,您应该始终将堆栈指针 (SP) 与偶数偏移量对齐。不要使用 0FFFFh 作为起始堆栈地址,而是使用 0000h。完成的第一个
PUSH
会将 SP 包装到 0FFFEh (0000h-0002h=0FFFEh) 之前将值写入堆栈。