ORA-00904 PL/SQL 中的无效标识符

问题描述

CREATE OR REPLACE PROCEDURE PURGE_PROGRAM
AS
BEGIN
   DECLARE
   v_param          VARCHAR2(3500);
   v_sql            VARCHAR2(500);
   v_purge_count    NUMBER(17);

  BEGIN
    SELECT param INTO v_param FROM ParaMETERS WHERE NAME='rententionPeriod';
    dbms_output.put_line('Param: '||v_param);

   IF v_param IS NOT NULL THEN
      SELECT COUNT(*) INTO  v_purge_count
      FROM
      (
         SELECT * FROM tbl1 WHERE Trunc(SYSDATE) - Trunc(UPDATE_DATE) > v_param
         UNION ALL
         SELECT * FROM tbl2 WHERE Trunc(SYSDATE) - Trunc(UPDATE_DATE) > v_param
      )x;

     v_sql := 'INSERT INTO tbl1_arc
               SELECT * FROM tbl1 WHERE Trunc(SYSDATE) - Trunc(UPDATE_DATE) > v_param';
EXECUTE IMMEDIATE v_sql;

     v_sql := 'INSERT INTO tbl2_arc
               SELECT * FROM tbl2 WHERE Trunc(SYSDATE) - Trunc(UPDATE_DATE) > v_param';
   EXECUTE IMMEDIATE v_sql;
   END IF;
  END;   
END PURGE_PROGRAM;
/

在上面的过程中，v_param 能够以正确的值输出，但是随后我得到异常 ORA-00904: "V_ParaM": invalid identifier 也许 v_param 无法从字符串 v_sql 访问？

解决方法

当我在需要执行的SQL字符串中引用v_param时，它必须是后面的代码

是的。 v_param 超出了您正在执行的动态 SQL 的范围。

您需要在动态 SQL 中使用绑定变量，并将值传入：

v_sql := 'INSERT INTO tbl1_arc
               SELECT * FROM tbl1 WHERE TRUNC(SYSDATE) - TRUNC(UPDATE_DATE) > :v_param';
EXECUTE IMMEDIATE v_sql USING v_param;

db<>fiddle

---

不直接相关，但在比较之前最好避免修改表列值；所以你可以这样做：

WHERE UPDATE_DATE > TRUNC(SYSDATE) - v_param

或者可能取决于您如何处理截止点 - 因此请检查返回哪些值以及您实际想要的值：

WHERE UPDATE_DATE >= TRUNC(SYSDATE) + 1 - v_param

这将允许使用 UPDATE_DATE 上的索引，并且即使没有索引也可以减少总体工作量。