理解 foldTree 函数的类型推导

编程问答 2022-05-12

问题描述

看看出现在 Data.Tree 中的这个定义：

foldTree :: (a -> [b] -> b) -> Tree a -> b
foldTree f = go where
    go (Node x ts) = f x (map go ts)

我的具体问题是：当go中的等式右侧出现(map go ts)名称时，函数的类型如何

(a -> [b] -> b)

被推断？

例如，有这行代码：

foldTree (:) (Node 1 [Node 2 []])

实例化定义：

foldTree (:) = go where
    go (Node 1 [Node 2 []]) = (:) 1 (map go [Node 2 []])

(:) 1 (map go [Node 2 []]) 没有被完全评估，所以我只看到 (:) 1 的类型为 Num a => [a] -> [a]。但是，缺少一个缺口，为了填补它，应该完成递归。所以，计算类型似乎有一定的循环性。

非常感谢任何见解。

解决方法

Haskell 的类型推断非常聪明！我不能告诉你这实际上是如何推断的，但让我们来看看它可能是怎样的。现实可能不会太远。在这种情况下实际上不需要类型签名。

foldTree f = go where
    go (Node x ts) = f x (map go ts)

foldTree 被定义为接受一个参数，而 go 被定义为接受一个参数，所以我们从一开始就知道这些是函数。

foldTree :: _a -> _b
foldTree f = go where
    go :: _c -> _d
    go (Node x ts) = f x (map go ts)

现在我们看到 f 用两个参数调用，所以它实际上必须是（至少）两个参数的函数。

foldTree :: (_x -> _y -> _z) -> _b
foldTree f = go where
    go :: _c -> _d
    go (Node x ts) = f x (map go ts)

由于 foldTree f = go 和 go :: _c -> _d，结果类型 _b 实际上必须是 _c -> _d *:

foldTree :: (_x -> _y -> _z) -> _c -> _d
foldTree f = go where
    go :: _c -> _d
    go (Node x ts) = f x (map go ts)

传递给 f（_y 类型）的第二个参数是 map go ts。由于 go :: _c -> _d，_y 必须是 [_d]

foldTree :: (_x -> [_d] -> _z) -> _c -> _d
foldTree f = go where
    go :: _c -> _d
    go (Node x ts) = f x (map go ts)

go 将其参数与 Node x ts 匹配，而 Node 是 Tree 的数据构造函数，因此 go 的参数 (_c ) 必须是 Tree。

foldTree :: (_x -> [_d] -> _z) -> Tree _p -> _d
foldTree f = go where
    go :: Tree _p -> _d
    go (Node x ts) = f x (map go ts)

Node 构造函数的第一个字段作为 f 的第一个参数传递，所以 _x 和 _p 必须相同：

foldTree :: (_x -> [_d] -> _z) -> Tree _x -> _d
foldTree f = go where
    go :: Tree _x -> _d
    go (Node x ts) = f x (map go ts)

由于go _被定义为f _ _，所以它们必须有相同类型的结果，所以_z是_d：

foldTree :: (_x -> [_d] -> _d) -> Tree _x -> _d
foldTree f = go where
    go :: Tree _x -> _d
    go (Node x ts) = f x (map go ts)

哇。现在编译器检查以确保这些类型有效（它们确实有效），并将它们从“元变量”（意味着推理引擎不知道它们代表什么类型的变量）“概括”为量化的类型变量（变量肯定是多态的），它得到

foldTree :: forall a b. (a -> [b] -> b) -> Tree a -> b
foldTree f = go where
    go :: Tree a -> b
    go (Node x ts) = f x (map go ts)

实际情况有点复杂，但这应该给你要点。

[*] 这一步有点作弊。我忽略了一个叫做“让泛化”的特性，它在这个上下文中是不需要的，它实际上被 GHC Haskell 中的几个语言扩展禁用了。

,

这是针对此问题的类型派生电子表格。将所有东西放在一起会更容易理解：

data Tree a = Node a [Tree a]

foldTree f = go  where
  go (Node x ts) = f x (map go ts)

foldTree f t = go t  where
  go t@(Node x ts) = f x (map go ts)
--------------------------------------
     Tree a                                  t  :: Tree a       from `data Tree a`
             a         a                     x  :: a            from `data Tree a`
              [Tree a]           [Tree a]    ts :: [Tree a]     from `data Tree a`
                              Tree a -> b    go :: Tree a -> b  from type of `map`
                          [b]                                   from type of `map`
               f  :: a -> [b] -> r                some resulting type `r`
               go :: Tree a   -> r                from definition of `go`
               go :: Tree a   -> b                as derived above
                     ----------------------
                               r ~ b              `r` and `b` are the same type
                     ----------------------
               f  :: a -> [b] ->   b              more precise type now
             ------------------------------
foldTree :: (a -> [b] -> b) -> Tree a -> b
foldTree    f               =  go

这里我们从 t 的类型开始，但无论起点如何，派生类型将始终相同，直到对其类型变量进行一致的重命名。

这个符号的解释：我们从上到下，从左到右阅读。我试图以一种暗示性的方式垂直对齐相关的事物。想象一下，你用它的类型对每个实体进行注释，在纸上写上靠近该实体的类型，上面有所有的代码（用蓝色写），用较小的字母和不同的颜色（比如红色）。相反，我们在该实体下编写类型，垂直对齐（即使它们之间还有一些其他的线）。

例如，推导部分的第二行有两个 a 写在 x 下，旁边还有一些注释。这一切意味着什么？

每个 a 都写在 x 下。就像我们已经用它的类型 x 注释了每个 a。由于 x 在两个实例中都是相同的 x，因此类型是相同的类型。我们还不太了解它，所以我们只是称它为 a —— 一个类型变量，如果它在推理过程中发生的话，可以在以后采用另一种更精细的含义。然后，有一个旁注：x :: a 是一个常规的 Haskell 符号，它意味着 x 的类型为 a。所以它说的是同样的事情，但更正式。然后是关于这个决定从何而来的非正式说明。

foldfoldhaskellhaskelltreetreetype-inferencetypestypestypes