为什么 Slime 的调试器不评估所选帧中的这个特定表达式？

问题描述

我正在尝试通过Common Lisp：符号计算的温和介绍这本书来学习 Common Lisp。此外，我正在使用 SBCL、Emacs 和 Slime。

在第 10 章结束时，作者讨论了有用的 break 函数。为了提供背景上下文，他提出了这个有问题的函数：


(defun analyze-profit (price commission-rate)
  (let* ((commission (* price commission-rate))
         (result
           (cond ((> commission 100) 'rich)
                 ((< commission 100) 'poor))))
    (format t "~&I predict you will be: ~S"
            result)
    result))

该函数按预期工作，在 REPL 中使用以下参数调用：

> (analyze-profit 1600 0.15)
I predict you will be: RICH
RICH

> (analyze-profit 3100 0.02)
I predict you will be: POOR
POOR

但是，当 commission 正好是 100 时，它显示错误的结果：

> (analyze-profit 2000 0.05)
I predict you will be: NIL
NIL

为了调试，作者在定义上插入了break函数：


(defun analyze-profit-debugging (price commission-rate)
  (let* ((commission (* price commission-rate))
         (result
           (cond ((> commission 100) 'rich)
                 ((< commission 100) 'poor))))
    (break "Value of RESULT is ~S" result)
    (format t "~&I predict you will be: ~S"
            result)
    result))

然后他检查控制栈，同时检查局部变量的值：

我知道调试器是出了名的依赖于实现。

在我的环境（emacs、slime、sbcl）中，我能够在 @Vindarel 编写的 great tutorial 之后重现类似的东西。

将点（光标）放在堆栈 0: 上并按下 e 后：

Backtrace:
  0: (ANALYZE-PROFIT-DEBUGGING 2000 0.05)
  1: (SB-INT:SIMPLE-EVAL-IN-LEXENV (ANALYZE-PROFIT-DEBUGGING 2000 0.05) #<NULL-LEXENV>)
  2: (EVAL (ANALYZE-PROFIT-DEBUGGING 2000 0.05))

我能够评估堆栈帧中的表达式。因此，我在 迷你缓冲区 上收到此消息：

Eval in frame (COMMON-LISP-USER)> price
=> 2000 (11 bits,#x7D0,#o3720,#b11111010000)

还有：

Eval in frame (COMMON-LISP-USER)> commission-rate
=> 0.05

不幸的是，我无法访问名为 local variable 的 commission 的主要问题：

Eval in frame (COMMON-LISP-USER)> commission

我期待：

100.0

但我收到一条错误消息：

变量 COMMISSION 未绑定。 [类型条件未绑定变量]

我仔细检查了拼写。此外，我还尝试使用 p 代替 e 并四处移动光标。然而，没有任何效果。

如何检查有问题的变量 commission 的值？

解决方法

如果您导航到调试器的顶部框架并在该框架上按 Enter，您将看到 commission 不被调试器识别为局部变量：

Value of RESULT is NIL
   [Condition of type SIMPLE-CONDITION]

Restarts:
 0: [CONTINUE] Return from BREAK.
 1: [RETRY] Retry SLIME REPL evaluation request.
 2: [*ABORT] Return to SLIME's top level.
 3: [ABORT] abort thread (#<THREAD "new-repl-thread" RUNNING {1002D65C93}>)

Backtrace:
  0: (ANALYZE-PROFIT-DEBUGGING 2000 0.05)
      Locals:
        COMMISSION-RATE = 0.05
        PRICE = 2000
        RESULT = NIL
  1: (SB-INT:SIMPLE-EVAL-IN-LEXENV (ANALYZE-PROFIT-DEBUGGING 2000 0.05) #<NULL-LEXENV>)
  2: (EVAL (ANALYZE-PROFIT-DEBUGGING 2000 0.05))
 --more--

这里的问题是编译器优化掉了一些调试信息。您可以使用文件开头的 declaim 或函数定义中的 declare 告诉编译器包含更多调试信息：

(defun analyze-profit-debugging (price commission-rate)
  (declare (optimize (debug 3)))
  (let* ((commission (* price commission-rate))
         (result
           (cond ((> commission 100) 'rich)
                 ((< commission 100) 'poor))))
    (break "Value of RESULT is ~S" result)
    (format t "~&I predict you will be: ~S"
            result)
    result))

赋予 debug 的数字可以是 0、1、2 或 3；更大的数字意味着应该更加重视保留调试信息。

现在在调试器中，在堆栈顶部按回车直接显示commission的值：

Backtrace:
  0: (ANALYZE-PROFIT-DEBUGGING 2000 0.05)
      Locals:
        COMMISSION = 100.0
        COMMISSION-RATE = 0.05
        PRICE = 2000
        RESULT = NIL
  1: (SB-INT:SIMPLE-EVAL-IN-LEXENV (ANALYZE-PROFIT-DEBUGGING 2000 0.05) #<NULL-LEXENV>)
  2: (EVAL (ANALYZE-PROFIT-DEBUGGING 2000 0.05))
 --more--

而且，在顶部堆栈帧上使用 e 命令现在可以按您最初预期的那样工作：

Eval in frame (COMMON-LISP-USER)> commission
=> 100.0

break common-lisp debugging debugging debugging stack-frame