Godot 引擎使用 Geometry 的 merge_polygons_2d() 方法合并两个以上的多边形

编程问答 2022-05-03

问题描述

考虑以下场景：给定 n 个 polygon2D 节点，它们的作用类似于“阴影”（黑色，alpha 值减半），如何使用 merge_polygons_2d() 方法将它们全部组合成一个 polygon2D 节点？>

3 个叠加多边形的示例。

使用以下硬编码代码，我成功地将所有三个多边形合并为一个。但我无法弄清楚如何通过迭代使过程自动化，以避免我的方法，例如有超过 10..20.. 多边形要合并。

func Merge_Map_Shadows() -> void:
# Get all "shadow" polygons and store them in an array,# then apply xform transform in order to retain it's position and rotation.
# After that,delete the original shadow.
if Map_Shadows.get_child_count() > 0:
    var _detected_shadows: Array = []
    for _shadow in Map_Shadows.get_children():
        var _transformed_polygon: PoolVector2Array = []
        for _vector in _shadow.polygon: _transformed_polygon.append(_shadow.transform.xform(_vector))
        _detected_shadows.append(_transformed_polygon)
        _shadow.call_deferred("queue_free")
    
    # Create the "master shadow" node
    var _master_shadow: polygon2D = polygon2D.new() ; _master_shadow.color = Color.black ; _master_shadow.color.a = 0.5
    
    # Manually merge two "shadows" to the third and than apply the result to the master node
    var _merged_shadow_1: Array = []
    var _merged_shadow_2: Array = []
    _merged_shadow_1 = Geometry.merge_polygons_2d(_detected_shadows[0],_detected_shadows[2])
    _merged_shadow_2 = Geometry.merge_polygons_2d(_merged_shadow_1[0],_detected_shadows[1])
    _master_shadow.set_polygon(_merged_shadow_2.front())
    
    Map_Shadows.add_child(_master_shadow)

结果正是我想要的。

节点结构上的多边形合并过程之前和之后。

谢谢， 迈克。

解决方法

因为您要删除和添加为同一节点的子节点。我会利用孩子的名单。

在开始之前，我们需要记住以下几点：

  • 并非所有节点都是 Polygon2D。
  • 并非所有 Polygon2D 都重叠。
  • Polygon2D 节点可能应用了非身份转换。

计划是将多边形合并到位。我将列出需要删除的多边形。稍后会回来。

让我们从迭代子项列表开始。我使用整数索引的原因稍后会有意义，所以我有：

for child_index in Map_Shadows.get_child_count():
    pass

我们当然需要孩子，所以：

for child_index in Map_Shadows.get_child_count():
    var child = Map_Shadows.get_child(child_index)

但我们需要确保它是一个 Polygon2D

for child_index in Map_Shadows.get_child_count():
    var child = Map_Shadows.get_child(child_index)
    var found_polygon:Polygon2D = child as Polygon2D
    if found_polygon == null:
        continue

此外，由于我们将从同一个列表中删除，我们需要考虑它可能会排队等待删除：

for child_index in Map_Shadows.get_child_count():
    var child = Map_Shadows.get_child(child_index)
    var found_polygon:Polygon2D = child as Polygon2D
    if found_polygon == null or found_polygon.is_queued_for_deletion():
        continue

接下来我们需要检查子节点是否应用了非身份转换，如果应用了，则撤消它：

if found_polygon.transform != Transform2D.IDENTITY:
    var transformed_polygon = found_polygon.transform.xform(found_polygon.polygon)
    found_polygon.transform = Transform2D.IDENTITY
    found_polygon.polygon = transformed_polygon

请注意，我们不需要遍历多边形的点。

现在我们将尝试将多边形与我们已经看到的所有多边形合并。为此，我们需要另一个循环。这看起来就像第一个，除了它上升到当前索引。 这就是我使用索引进行迭代的原因。

    for child_subindex in child_index:
        var other_child = Map_Shadows.get_child(child_subindex)
        var other_found_polygon:Polygon2D = other_child as Polygon2D
        if other_found_polygon == null or other_found_polygon.is_queued_for_deletion():
            continue

现在我们尝试合并：

        var merged_polygon = Geometry.merge_polygons_2d(found_polygon.polygon,other_found_polygon.polygon)

如果他们合并，我们得到一个包含单个项目（合并的多边形）的数组，如果不是这样，他们没有合并。因此：

    if merged_polygon.size() != 1:
        continue

最后，当它们合并时，我们将删除当前多边形（好吧，我们将把它放在一个数组中以便稍后删除它）并将另一个设置为合并的多边形：

    other_found_polygon.polygon = merged_polygon[0]
    polygons_to_remove.append(found_polygon)
    break

我在这里中断是因为我们已经找到了一个多边形来合并当前的多边形。无需继续寻找。

当然，单次通过多边形可能无法完成所有合并。因此，将整个内容放在一个 while(true) 循环中，如下所示：

var polygons_to_remove:Array
while(true):
    polygons_to_remove = []

    # the rest of the code here

    if polygons_to_remove.size() == 0:
        break

    for polygon_to_remove in polygons_to_remove:
        polygon_to_remove.queue_free()

正如我在开始时所说的，我们保留了一个需要删除的多边形的列表（好吧，一个数组）。

如果我们没有合并任何多边形，那么我们也不必删除任何多边形。这意味着我们已经完成了。这就是为什么当要删除的多边形列表为空时我们break退出 while(true) 循环的原因。

当然，如果列表不为空，我们实际上需要删除那些节点。所以对它们调用 queue_free。不，我们不需要call_deferred，事实上，我们不需要call_deferred，因为我们正在检查is_queued_for_deletion，所以我们需要立即将它们排入队列。

而且因为人们喜欢复制和粘贴，这是完整的相关代码：

var polygons_to_remove:Array
while(true):
    polygons_to_remove = []
    for child_index in Map_Shadows.get_child_count():
        var child = Map_Shadows.get_child(child_index)
        var found_polygon:Polygon2D = child as Polygon2D
        if found_polygon == null or found_polygon.is_queued_for_deletion():
            continue

        if found_polygon.transform != Transform2D.IDENTITY:
            var transformed_polygon = found_polygon.transform.xform(found_polygon.polygon)
            found_polygon.transform = Transform2D.IDENTITY
            found_polygon.polygon = transformed_polygon

        for child_subindex in child_index:
            var other_child = Map_Shadows.get_child(child_subindex)
            var other_found_polygon:Polygon2D = other_child as Polygon2D
            if other_found_polygon == null or other_found_polygon.is_queued_for_deletion():
                continue

            var merged_polygon = Geometry.merge_polygons_2d(found_polygon.polygon,other_found_polygon.polygon)
            if merged_polygon.size() != 1:
                continue

            other_found_polygon.polygon = merged_polygon[0]
            polygons_to_remove.append(found_polygon)
            break

    if polygons_to_remove.size() == 0:
        break

    for polygon_to_remove in polygons_to_remove:
        polygon_to_remove.queue_free()

是的，我测试了那个东西。有用。但是，我假设这些都是表现良好的多边形。可能存在边缘情况。特别是，我没有使用少于三个顶点的 Polygon2D、具有 Polygon2D 的 invert_enable 或具有 Polygon2D 集的 polygons 进行测试（参见 { {3}}）。

我还可以考虑进一步优化：我们只需要检查在先前通过中合并的多边形之间的进一步合并。如果一个多边形在没有合并的情况下完成了一次传递，则意味着它是孤立的，我们不需要继续检查那个。

gdscriptgeometrygodotpolygon