是`const`字符串参数线程安全吗

问题描述

| 这段代码

procedure MyThreadTestA(const AStr: string);

比

procedure MyThreadTestB(AStr: string);

在执行相同的工作时，两者都传递一个指针。 但是，版本B“正确地”更新了

AStr

的引用计数并在我更改它的情况下进行了复制。 版本A仅传递一个指针，只有编译器阻止我更改

AStr

。 如果我在汇编程序中做一些恶作剧或以其他方式规避编译器保护，则版本A不安全，这是众所周知的，但是... 通过引用将

AStr

作为

const

参数线程安全吗？ 如果

AStr

在其他线程中的引用计数变为零并且字符串被销毁，会发生什么情况？     

解决方法

不，此类技巧不是线程安全的。

Const

防止添加引用，因此另一个线程进行的更改将以不可预测的方式影响该值。示例程序，尝试更改

P

的定义中的

const

：

{$apptype console}
uses SysUtils,Classes,SyncObjs;

type
  TObj = class
  public
    S: string;
  end;

  TWorker = class(TThread)
  public
    procedure Execute; override;
  end;

var
  lock: TCriticalSection;
  obj: TObj;

procedure P(const x: string);
// procedure P(x: string);
begin
  Writeln(\'P(1): x = \',x);
  Writeln(\'Releasing obj\');
  lock.Release;
  Sleep(10); // give worker a chance to run
  Writeln(\'P(2): x = \',x);
end;

procedure TWorker.Execute;
begin
  // wait until TMonitor is freed up
  Writeln(\'Worker started...\');
  lock.Acquire;
  Writeln(\'worker fiddling with obj.S\');
  obj.S := \'bar\';
  TMonitor.Exit(obj);
end;

procedure Go;
begin
  lock := TCriticalSection.Create;
  obj := TObj.Create;
  obj.S := \'foo\';
  UniqueString(obj.S);
  lock.Acquire;
  TWorker.Create(False);
  Sleep(10); // give worker a chance to run and block
  P(obj.S);
end;

begin
  Go;
end.

但这不仅限于线程。修改基础变量位置具有类似的效果：

{$apptype console}
uses SysUtils,SyncObjs;

type
  TObj = class
  public
    S: string;
  end;

var
  obj: TObj;

procedure P(const x: string);
begin
  Writeln(\'P(1): x = \',x);
  obj.S := \'bar\'; 
  Writeln(\'P(2): x = \',x);
end;

procedure Go;
begin
  obj := TObj.Create;
  obj.S := \'foo\';
  UniqueString(obj.S);
  P(obj.S);
end;

begin
  Go;
end.

    ,补充一下Barry的回答：如果传递的字符串来自调用方范围内的局部变量，则绝对是线程安全的。 在那种情况下，本地变量将保存有效的引用，并且唯一的方式（假设仅是有效的Pascal代码，而在asm中没有摆弄）要更改的本地变量是您的调用返回。 这还包括所有字符串变量的源是函数调用的结果的情况（包括属性访问，例如TStrings.Strings []），因为在这种情况下，编译器必须将字符串存储在本地temp变量中。 仅当您在调用返回之前直接从可以更改字符串的位置（通过相同或另一个线程）传递字符串时，才会导致线程安全问题。