SPARQL：有没有办法以属性为中心？ 替代方案

问题描述

我正在查询具有 3 个维度和 1 个度量的 DataCube（RDF 统计数据）。在这个数据立方体中，每个观察结果由 4 个语句组成（3 个用于维度，1 个用于度量，如下例所示（可以在 http://kaiko.getalp.org/sparql 处查询）。

SELECT distinct ?version ?lg ?relation ?count WHERE {
  ?o a qb:Observation; 
    qb:dataSet dbnstats:dbnaryNymRelationsCube;
    dbnary:wiktionaryDumpVersion ?version;
    dbnary:observationLanguage ?lg;
    dbnary:nymRelation ?relation;
    dbnary:count ?count.
} 

查询返回如下内容：

版本	lg	关系	计数
“20210601”	“id”	反义词	4
“20210601”	“id”	近似同义词	0
“20210601”	“id”	上位词	0
“20210601”	“id”	同义词	108
“20150602”	“id”	反义词	2
“20150602”	“id”	近似同义词	0
“20150602”	“id”	上位词	0
“20150602”	“id”	同义词	36
“20150702”	“id”	反义词	2
“20150702”	“id”	近似同义词	0
“20150702”	“id”	上位词	0
“20150702”	“id”	同义词	36

我想根据关系的值来获得下表：

版本	lg	反义词	近似同义词	上位词	同义词
“20210601”	“id”	4	0	0	108
“20150602”	“id”	2	0	0	36
“20150702”	“id”	2	0	0	36

我找不到一种方法来制作单个 SPARQL 查询来获取此信息。目前，我需要获取所有数据并使用我使用的任何客户端语言（此处为 python）进行数据透视。

这在 SPARQL 1.1 中可行吗？怎么样？

我宁愿有一个一般性的答案，但接入点目前由 Virtuoso 提供服务。

编辑：为了更好地解释我的期望。在 DataCube Vocabulary 中，描述了 DataCube 的结构，它给出了不同的维度和度量（通常通过本体）。因此，查询开发者认为维度和度量是已知的（至少对于本体的特定版本）。

这里，nymRelation 的值是事先未知的，它们是数据的一部分，而不是结构的一部分。 Pivot 操作似乎是对 DataCube 的有效操作（以及切片、投影等）。

我想知道是否可以在服务器上进行这样的操作（通过不依赖于服务器上实际数据的通用查询）。这将使客户端可以维护一个 LAZY 数据立方体对象并在确实需要结果时推迟实际的数据透视操作。

我怀疑（并且第一个答案似乎暗示）如果不获取整个 DataCube（在客户端的内存中执行操作）或获取实际的不同属性值并自动制作一个查询，则此操作是不可能的取决于第一个结果。

解决方法

您需要组合来自不同观察的值。如果对查询中的关系名称进行硬编码不太不切实际，您可以编写单独的 SELECT 语句，将 ?version 和 ?lg 的公共值绑定到一个单一的解决方案中，如下所示：

SELECT ?version ?lg ?antonym ?approximateSynonym # ...
WHERE {
  {
    SELECT ?version ?lg ?antonym
    WHERE
    {
      ?o1 a qb:Observation; 
        qb:dataSet dbnstats:dbnaryNymRelationsCube;
        dbnary:wiktionaryDumpVersion ?version;
        dbnary:observationLanguage ?lg;
        dbnary:nymRelation dbnary:antonym;
        dbnary:count ?antonym .   # <--- bind the antonym count value
    }
  } 

  {
    SELECT ?version ?lg ?approximateSynonym 
    WHERE
    {
      ?o2 a qb:Observation; 
        qb:dataSet dbnstats:dbnaryNymRelationsCube;
        dbnary:wiktionaryDumpVersion ?version;
        dbnary:observationLanguage ?lg;
        dbnary:nymRelation dbnary:approximateSynonym;
        dbnary:count ?approximateSynonym .   # <--- bind the approximateSynonym count
    }
  }

  # ... And so on for the other columns 
}

这要求提供每个版本/语言组合的所有统计信息；否则，该组合将无解。

替代方案

如果关系类型太多，可以使用下面的 CONSTRUCT 查询将每一行的等价物聚合到它自己的类似观察的对象中。不同的属性将映射到相同的 ?rowURI。您可以将此结果解析为 RDF，也可以根据需要处理 json 序列化。

CONSTRUCT {
    ?rowURI 
       dbnary:wiktionaryDumpVersion ?version ;
       dbnary:observationLanguage ?lg ;
       ?relation ?count 
}
WHERE {
  ?o a qb:Observation; 
    qb:dataSet dbnstats:dbnaryNymRelationsCube;
    dbnary:wiktionaryDumpVersion ?version;
    dbnary:observationLanguage ?lg;
    dbnary:nymRelation ?relation;
    dbnary:count ?count.

    BIND(URI(CONCAT("http://example.org/row/",?lg,?version)) AS ?rowURI)
}